spec.mock

script = require '../mixco/script'
{assert} = require '../mixco/util'

exports.engine = ->
    obj = createSpyObj 'engine', [
        'getValue',       # (group, key)
        'setValue',       # (group, key, value)
        'softTakeover',   # (group, key, enable)
        'beginTimer',     # (delay, handler) -> id
        'stopTimer',      # (id)
        'connectControl', # (group, key, handler[, disconnnect])
        'scratchEnable',  # (int deck, int intervalsPerRev, float rpm,

        'scratchTick',    # (int deck, int interval)
        'scratchDisable', # (int deck)
        'isScratching',   # (int deck)
        'brake',          # (int deck, bool activate[, float factor, rate])
        'spinback',       # (int deck, bool activate[, float factor, rate])
        ]

    do ->
        values = {}
        obj.getValue.andCallFake (group, key) ->
            values[[group, key]] ? 0
        obj.setValue.andCallFake (group, key, value)->
            values[[group, key]] = value

    obj.connectControl.andCallFake do ->
        connections = {}
        (group, key, handler, disconnect) ->
            id = [group, key, handler]
            if disconnect
                assert id of connections,
                    "Disconnect not connect control: #{group}, #{key}"
                delete connections[id]
            else
                assert id not of connections,
                    "Connect connected control: #{group}, #{key}"
                connections[id] = true
    obj

exports.midi = ->
    createSpyObj 'engine', [
        'sendShortMsg', # (status, id, value)
        'sendSysexMsg', # (data, length)
        ]

exports.script = ->
    createSpyObj "script", [
        'pitch', # (control, value, status)
        ]

exports.mixxx = ->
    engine: exports.engine()
    midi:   exports.midi()
    script: exports.script()

class exports.TestScript extends script.Script

    @property 'mixxx',
        get: ->
            @_fakeMixxx or= exports.mixxx()

exports.testScript = -> new exports.TestScript arguments...